% special punk letter combinations

beginpunkchar(oct"035",16,1,2);  % \AE
z1=pp(1.5u,0); z2=pp(.6w,h); z3=pp(w-1.5u,h);
pd z1; pd z3; draw z1--z2--z3;  % left diagonal and upper arm
z4=pp .3[z1,z2]; z5=pp(.6w,0); z6=pp(w-2u,.3h);
pd z4; pd z6; draw z4--z6; % crossbar
z7=pp(w-u,0); pd z2; pd z7; draw z2--z5--z7; % stem and lower arm
endchar;

beginpunkchar(oct"036",18,1,2); % \OE
z1=pp(.5w,h); z2=pp(u,.4h); z3=pp(.5w,0);
pd z1; draw z1..z2..{right}z3; % bowl
z4=pp(w-1.5u,h); z5=pp(w-2u,.4h); z6=pp(w-u,0);
pd z4; pd z6; draw z4--z1--z3--z6; % arms and stem
pd z5; draw z5--.4[z3,z1];  % crossbar
endchar;

beginpunkchar(oct"037",14,1,1); % \O
z1=pp(.5w,h); z2=pp(u,.5h); z3=pp(.5w,0); z4=pp(w-u,.5h);
z5=pp(w-2u,1.1h); z6=pp(2u,-.1h);
pd z1; pd z6; draw z1..z2..z3..z4..z5--z6;  % bowl and diagonal
endchar;
